/* *****************************************
 ******  "TILE FLIP" by John Park ***********
 ******  Harmonic Lab / UofO, 5/25/12 *******
 *******************************************/

//DECLARATIONS
PFont font; 
int coll = 21;          // This of as X axis (columns)
int rows = 15;          // Think of as Y axis (rows)
int count = rows*coll;  //Total count of squares

//Arrays data for rectangle tiles
float [] rotValue = new float [count]; // Array to hold rotational values
color []clr = new color[count];        // Array to hold color vals


void setup() {
  size(1024, 768, P3D); 
  font = loadFont("SansSerif-24.vlw");
  textFont(font, 12); 
  textAlign(CENTER);
  noStroke();
  
  // Set all rotation vals to 0 and color vals to purple
  for (int c=0; c<count; c++) {
    rotValue[c] = 0;
    clr[c] = color(225, 205, 245, 180);
  }
}

void draw() {
  background(0);
  for (int i=0; i<rows; i++) {
    for (int v=0; v<coll; v++) {
      fill(255, 30);
      text(i*coll+v, v*(width/coll)+(width/coll/2), i*(height/rows)+(height/rows/2)+10, 0); // Write text for boxes for debugging
      
      pushMatrix();
      translate(v*(width/coll), i*(height/rows), 0);
      rotateX(rotValue[i*coll+v]);
      fill(clr[i*coll+v]);
      rect(0, 0, float(width)/coll, float(height)/rows);
      popMatrix();
    }
  }
}

void mousePressed() {
  int range = 3;
  float mx=0;
  float my=0;
  for (int i=0; i<rows; i++) {
    for (int v=0; v<coll; v++) {
      mx = floor(map(mouseX, 0, width, 0, coll));
      my = floor(map(mouseY, 0, height, 0, rows));
      //println("mx is: "+mx);
      PVector rloc = new PVector(v, i, 0);
      PVector click = new PVector(mx, my, 0); 
      float d=  PVector.dist(rloc, click);

      //println("Delta mouse & box: "+(v*rows+i)+"is: "+floor(d));

      if (d<=range) {
        clr[i*coll+v] = color(205, 185, 225, 180);
        rotValue[i*coll+v] += (radians((range-d))*11);  // change the multiplier at end to increase rotational sensitivity
      }
      // println("x is: "+int(map(mouseX,0,width,0,coll)));
      //println("y is: "+int(map(mouseY,0,height,0,rows)));     
      //clr[int(float(mouseX)/width*(width/coll)*rows+float(mouseY)/height*(height/rows))] = color(255,0);
    }
  }
  clr[int(my)*coll+int(mx)] = color(255, 0, 0);  // Turns clicked box red
}